Toujours à l'heure avec les modules d'horloge temps REAL DS1307 et DS3231

Placé sur 2016-07-16

Modules d'horloge en temps REAL

Versions d'horloge en temps REAL

La série d'horloges REAL contient de nombreux numéros de type différents, tous avec des fonctionnalités comparables. Dans cette série, seules 2 versions sont « grand public », à savoir la DS1307 et le DS3231. Ces puces ont toutes deux la possibilité de connecter une batterie et ont une broche de sortie sqw, avec laquelle le contrôleur peut recevoir une impulsion d'horloge de (1 Hz, 1,024 kHz, 4,096 kHz, 8,192 kHz). Les deux CI ont également une interface One-Wire, ce qui permet de les connecter via I²s'adresser à C.

Module d'horloge en temps REAL DS1302 - SPILe module d'horloge temps REAL DS1302 possède une interface SPI à travers laquelle il peut indiquer l'heure. Disponible immédiatement € 1,85

Module horloge en temps REAL DS3231Module d'horloge en temps REAL avec la puce DS3231. Ce module garantit que l' Arduino connaît l'heure exacte à tout moment. En connectant l' Arduino à la broche 'qw', il est possible de générer une interruption toutes les secondes avec laquelle des valeurs de capteur ou un affichage peuvent être adressés. Rupture de stock € 10,25

Connexion du module RTC à l' Arduino UNO

Les modules RTC se présentent sous différentes formes et tailles, mais la connexion à l' Arduino est la même pour tous les modules. Le module doit dans tous les cas être alimenté en 5V, de plus l'interface I2C devra être connectée aux broches SDA (Serial data) SCL (Serial clock) de l' Arduino (ce sont les broches A4 et A5 sur l' Arduino UNO). De plus, la sortie SQW peut être connectée à n'importe quelle broche de l' Arduino pour recevoir une impulsion d'horloge du RTC.

Connexion DS1307 Arduino UNO

Code C.-B.

Les valeurs numériques dans les puces RTC sont stockées au format BCD. Le code BCD est plus facile à utiliser que les nombres décimaux au niveau matériel, mais ces codes ne sont pas très utiles dans les logiciels. Les numéros vers et depuis la puce doivent donc être encodés et décodés pour que le contrôleur et le RTC se comprennent.

// Convert decimal to BCD
byte decToBcd(byte val)
{
  return( (val/10*16) + (val%10) );
}
//Convert BCD to decimal
byte bcdToDec(byte val)
{
  return( (val/16*10) + (val%16) );
}

Ecrire l'heure actuelle sur le RTC

L'heure n'a besoin d'être écrite qu'une seule fois sur le RTC lorsqu'il est connecté à la batterie. Le RTC lui-même garde le temps et continue de compter, même lorsqu'il n'est pas connecté au contrôleur.

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setDS3231time(
    byte second, 
    byte minute, 
    byte hour, 
    byte dayOfWeek, 
    byte dayOfMonth, 
    byte month, 
    byte year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //set next input to start at the seconds register
  Wire.write(0); 
  
  //set seconds
  Wire.write(decToBcd(second)); 
  //set minutes
  Wire.write(decToBcd(minute)); 
  //set hours
  Wire.write(decToBcd(hour)); 
  //set day of week (1=Sunday, 7=Saturday)
  Wire.write(decToBcd(dayOfWeek));  
  //set date (1 to 31)
  Wire.write(decToBcd(dayOfMonth)); 
  //set month
  Wire.write(decToBcd(month));
  //set year 20(0 to 99)
  Wire.write(decToBcd(year)); 
    
  Wire.endTransmission();
}

Horloge du disque dur

De tijd van de RTC lezen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void readDS3231time(
    byte *second,
	byte *minute,
	byte *hour,
	byte *dayOfWeek,
	byte *dayOfMonth,
	byte *month,
	byte *year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  //set DS3231 register pointer to 00h
  Wire.write(0); 
  Wire.endTransmission();
      
  //request seven bytes of data from DS3231
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}

Afficher l'heure

Avec ces fonctions ensemble, le temps peut être déterminé par l' Arduino . Avec la fonction ci-dessous, ces données sont écrites sur le moniteur série, mais les possibilités d'affichage de l'heure sont infinies.

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  //set the initial time (only once, not every startup)
  //seconds, minutes, hours, dayofweek, day, month, year
  //11:00:00, Saturday, 2016-07-16
  setDS3231time(00,00,11,7,16,7,16);
}

void displayTime()
{
  byte second, minute, hour; 
  byte dayOfWeek, dayOfMonth, month, year;
  
  //retrieve data
  readDS3231time(&second, &minute, &hour, &dayOfWeek, 				     &dayOfMonth, &month, &year);
    
  //Hour
  Serial.print(hour, DEC);
  Serial.print(":");
  //Minute (+0 if needed)
  if (minute<10)
  {
    Serial.print("0");
  }
  Serial.print(minute, DEC);
  Serial.print(":");
  //Second (+0 if needed)
  if (second<10)
  {
    Serial.print("0");
  }
  Serial.print(second, DEC);
  Serial.print(" ");
    
  //Day
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  //Month
  Serial.print(month, DEC);
  Serial.print("/");
  //Year
  Serial.print(year, DEC);
}


void loop()
{
  displayTime(); 
  delay(1000);
}

SQW frequentie instellen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //move pointer to SQW address
  Wire.write(0x07); 
 
  //set output clock speed
  //0x00 = Off
  //0x10 = 1Hz
  //0x11 = 4.096Hz
  //0x12 = 8.192Hz
  //0x13 = 32.768Hz
  Wire.write(0x10);
 
  Wire.endTransmission();  
}

Avec ce code, une horloge complète peut être construite, qui peut afficher l'heure. Cela peut être fait sur un affichage à 7 segments, comme une horloge analogique, avec des signaux de fumée ou même parlé sur demande. De plus, l'heure peut aussi être utilisée en domotique/domotique, la cafetière s'allume à 8h du matin, le micro-onde à 17h15 le soir et les rideaux se ferment à 19h01:05. Tout est possible.

Posté par Robin Blok Site Internet Je m'intéresse à l'électronique, à la programmation et surtout à la combinaison des deux. Pour Opencircuit j'écris des blogs dans lesquels j'explique le fonctionnement de l'électronique et des modules.