Construisez votre propre téléscripteur Bluetooth

Placé sur 2017-11-13

Exemple de téléscripteur

Fournitures

Arduino Uno R3 - cloner Disponible immédiatement Ou un Arduino Nano € 11,40 Module matriciel MAX7219 4x Rupture de stock C'est l'affichage, il en faut au moins 1, 2 c'est encore mieux ! € 10,10 Module Bluetooth HC-06 avec adaptateur - clone Disponible immédiatement Ceci est l'esclave Bluetooth HC-06, vous avez besoin de 1 € 8,40 Résistance à film métallique 5,6KΩ 1/4W - 100 pièces Rupture de stock Le diviseur de tension pour le module Bluetooth € 1,45 Résistance à film métallique 10KΩ 1/4W - 10 pièces Disponible immédiatement Le diviseur de tension pour le module Bluetooth € 1,75 Alimentation Mean well SGA12E09-P1J - 9V 1,33A Disponible immédiatement Pour plus de puissance, USB ne peut pas fournir suffisamment € 13,90 Prise DC intégrée 5,5 mm x 2,1 mm - 5 pièces Rupture de stock € 2,45 Total € 49,45

L'horaire:

Le schéma montre comment tout doit être connecté. Si vous avez déjà une sensation de rotation de tous ces fils, ne regardez pas trop l'ensemble, mais essayez de considérer et de connecter les modules un par un. Vous verrez que ce n'est pas trop mal.

Le schéma ne montre qu'un seul module LED matriciel quadruple, en réalité vous pouvez en lier deux ensemble pour une double largeur !

Schéma de connexion du panneau d'affichage

Le module Bluetooth nécessite une petite attention supplémentaire. Les signaux de communication Bluetooth (TX et RX) fonctionnent à 3,3 volts, tandis que l' Arduino fonctionne à 5 volts. Les deux résistances réduiront les 5 volts d' Arduino à environ 3,3 volts.

L'alimentation :
Vous pouvez voir qu'une alimentation de 5 volts est utilisée. Vous devez. Un Arduino connecté en USB ne peut pas fournir assez de courant pour alimenter la matrice LED, surtout avec une double matrice.

Bibliothèque et esquisse Arduino :

L'esquisse Arduino utilise deux bibliothèques externes, pour les installer, recherchez MD_MAX72xx dans le gestionnaire de bibliothèques. Installez ensuite MD_Max72xx et MD_Parola

Ticker USB Bibliothèque Arduino

Définissez le bon module :
Après avoir installé les bibliothèques, nous devons indiquer à la bibliothèque MD_Max72xx quel module de matrice de leds nous utilisons.

Localisez le fichier sur votre disque dur : MD_MAX72xx.h
(probablement dans le dossier C:\Users\votre nom\Documents\ Arduino \libraries\MD_MAX72XX\src\)

//Op regel 214, zie je staan:   
#define   USE_PAROLA_HW   1, verander die 1 in 0

//Op regel 237 zie je staan: 
#define   USE_FC16_HW   0,   verander die 0 in 1.

Le croquis Arduino :

Ensuite, nous pouvons maintenant charger le croquis.
Copiez le croquis et collez le code dans le logiciel Arduino , sélectionnez le bon port com et tapez Arduino et appuyez sur upload !

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <SoftwareSerial.h>
#include <EEPROM.h>
#define MAX_DEVICES 8
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

// Use softserial for the bluetooth module
SoftwareSerial mySerial(2, 3);

// HARDWARE SPI
MD_Parola LK = MD_Parola(CS_PIN, MAX_DEVICES);

uint8_t scrollSpeed = 30;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define  BUF_SIZE  75
char curMessage[BUF_SIZE];
char newMessage[BUF_SIZE];
bool newMessageAvailable = false;

void setup()
{
  // Enable the next line to clear the message from eeprom.
  // EEPROM.write(0,1);
  
  mySerial.begin(9600); 
  delay(500);
  
  // The next line configures the BT-04 (BT-06) Module to NOT report connection status. 
  mySerial.write("\r\nAT+ENABLEIND0\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  // change the name of the BT-04 (BT-06) device, this will not work for HC-06
  mySerial.write("AT+NAMELichtkrant01\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  LK.begin();
  LK.displayClear();
  LK.displaySuspend(false);
  LK.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);  

  // Get the last message from EEPROM
  getMessageFromEeprom();
}


void loop()
{  
  readSerial();
  if (LK.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      storeMessageInEeprom();
    }
    LK.displayReset();
  }
}


  
void readSerial(void) {
  static char *cp = newMessage;
  while (mySerial.available())  
  {
    *cp = (char)mySerial.read();
    if ( (*cp == '\r') || (*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string   
      cp = newMessage;
      newMessageAvailable = true;
      mySerial.print("Nieuwe Boodschap = ");
      mySerial.println(newMessage);
      ClearRXbuffer();
    }
    else  // move char pointer to next position
      cp++;
  }
}


void storeMessageInEeprom(){
  // Store the message in EEPROM
  EEPROM.write(0,251);
  int i=0;
  char c=curMessage[i];
  while (c !=0){
    EEPROM.write(i+1,c);
    i++;
    c=curMessage[i];
    }
    EEPROM.write(i+1,0);
}

void getMessageFromEeprom(){
  if (EEPROM.read(0)!=251){
    strcpy(curMessage, "Hello! Please Send new message over bluetooth");
    newMessage[0] = '\0';
    } else {      
      int i=0;
      char c = EEPROM.read(i+1);
      while (c!=0){
        curMessage[i++]=c;
        c = EEPROM.read(i+1);
        }
        curMessage[i] = '\0';
        newMessageAvailable=false;         
    }
}

void ClearRXbuffer(){
  while (mySerial.available()){
    char c=mySerial.read(); 
    delay(5);
    } 
}

Si tout va bien (et pourquoi pas ?), vous verrez maintenant le message "Bonjour, veuillez envoyer un nouveau message via Bluetooth". Il est donc grand temps d'installer l'application Android sur votre téléphone et d'envoyer un nouveau message via Bluetooth !

L'application Androïd :

Pour modifier le texte sur le téléscripteur, nous avons besoin d'un programme de terminal Bluetooth, par exemple le Serial Bluetooth Terminal de Kai Morich, via le Magasin d'applications.

SérieBluetoothTerminal

Le fonctionnement de l'application est assez explicite, mais dans la vidéo, je le montre étape par étape.

borne bluetooth

Attention : l'iOS d'Apple ne peut pas se connecter au module Bluetooth utilisé, cela ne fonctionne donc qu'avec les appareils Android.

voir la vidéo

Y a-t-il encore des ambiguïtés ? Vous pouvez tout voir de plus près dans cette vidéo.

Posté par Bart Venneker Site Internet | Youtube Bart Venneker est un amateur d'électronique et réalise des vidéos éducatives sur l'électronique, Arduino et les imprimantes 3D.

Commentaires

Ad Laat

Malheureusement, les réglages sont introuvables dans la bibliothèque, ce qui fait que le ticker ne fonctionne pas, ce qui est dommage ! Une version différente aurait-elle pu être utilisée ? Salutations, Ad de Laat

Placé sur 19 novembre 2023

