Arduino Leonardo - Serrure électronique

Placé sur 2020-06-22

Obtenir le code à partir de l'entrée de l'utilisateur

Donc, comme je l'ai décrit dans la partie 1, nous devons obtenir toutes les entrées requises de l'utilisateur et vérifier le code avec celui enregistré.

Et vérifiez également si l'affichage ne déborde pas. Cela est géré par ce code.

GetCode function

const unsigned char MaxPasscodeLength = 19;
unsigned char PasscodeLength;
char Data[MaxPasscodeLength];
char Master[MaxPasscodeLength];

unsigned char data_count = 0;
char Key;

void GetCode() {							// This piece of code handles getting the code from the user
   if (data_count < MaxPasscodeLength) {
    Data[data_count] = Key; 
    lcd.setCursor(data_count,1); 
    lcd.print("*");
    if (EnableDebug) {
      Serial.println();
      Serial.print("Data_count: ");
      Serial.println(data_count);
      Serial.print("Data: ");
      Serial.println(Data[data_count]);
    }
    data_count++;
   }
   else {
      lcd.setCursor(data_count,1);
      lcd.print("*");
      lcd.setCursor(0, 3);
      lcd.print("Passcode Overflow");
      if (EnableDebug) {
        Serial.println();
        Serial.println("Passcode Overflow Error");
      }
      _delay_ms(1000);
      lcd.clear();
      clearData();
   }
}

Vérification du code

Nous devons également vérifier si le code correspond au code enregistré, afin que nous sachions quand nous pouvons ouvrir la serrure et quand nous ne le faisons pas.

CheckCode Function

void CodeCorrect() {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Correct");
  LockState = true;
  _delay_ms(1000);
  if (EnableDebug) {
    Serial.println();
    Serial.println("Opened");
  }
}

void CodeIncorrect() {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Incorrect");
  if (EnableDebug) {
    Serial.println();
    Serial.println("Incorrect PSWD");
  }
  LockState = false;
  _delay_ms(1000);
}

void OpenLock() {
  if (EnableServo) {
    Lock.write(90);
  }
  lcd.setCursor(0,0);
  lcd.print("Lock Opened");
  lcd.setCursor(0,2);
  lcd.print("Press -* to lock");
  if (EnablePasscodeChange) {
    lcd.setCursor(3,3);
    lcd.print("-# to change code");
  }
  TimeLastActivity = millis();
}

void CloseLock() {
  if (EnableServo) {
    Lock.write(180);
  }
  LockState = false;
  lcd.clear();
  if (EnableDebug) {
    Serial.println();
    Serial.println("Closing");
  }
  TimeLastActivity = millis();
}

void CheckCode() {
  if(data_count == PasscodeLength){
      Data[PasscodeLength] = 0;
      _delay_ms(500);
      lcd.clear();
      if (EnableDebug) {
        Serial.println();
        Serial.print("Data:   ");
        Serial.println(Data);
        Serial.print("Master: ");
        Serial.println(Master);
      }
      if(!strcmp(Data, Master)){
          CodeCorrect();
        }

      else{
          if (EnableDebug) {
            Serial.println();
            Serial.print("PasscodeLength: ");
            Serial.println(PasscodeLength);
            Serial.print("DataCount: ");
            Serial.println(data_count);
          }
          CodeIncorrect();
        }
  }
  else {
      if (EnableDebug) {
        Serial.println();
        Serial.print("Data:   ");
        Serial.println(Data);
        Serial.print("Master: ");
        Serial.println(Master);
        Serial.println();
        Serial.print("PasscodeLength: ");
        Serial.println(PasscodeLength);
        Serial.print("DataCount: ");
        Serial.println(data_count);
      }
      CodeIncorrect();
    }
  lcd.clear();
  clearData();
}

Page précédente 7. Le code - partie 2 - L'écran LCD Page actuelle 8. Le code - partie 3 - Le code Page suivante 9. Le code - partie 4 - Plus de codes 1. Introduction 2. Le schéma 3. Le clavier 4. Le module LCD 5. L'asservissement 6. Le code - partie 1 - Le clavier 7. Le code - partie 2 - L'écran LCD 8. Le code - partie 3 - Le code 9. Le code - partie 4 - Plus de codes 10. Le code - partie 5 - Configuration et boucle 11. Le code complet Posté par Sander Speetjens

Arduino Leonardo - Serrure électronique

Obtenir le code à partir de l'entrée de l'utilisateur

GetCode function

Vérification du code

CheckCode Function

Commentaires